[HOWTO - RAMDRIVE] Increasing SWTOR System Performance

Mineria · February 15, 2012

Step 3 of Lemon_King states "Scrolling down you should see a folder called SWTOR, open it and Copy the settings folder to <SWTOR Install Location>\Star Wars-The Old Republic\SWTOR\retailclient\". Because we want to keep our settings as we move the SWTOR folder in local to the ram. So the client looks at local swtor, get directed to the ramdisk and searches there for the settings, but then again got directed to the settings folder in retailclient. This all for keeping settings between reboots n stuff.

That doesn't make any sense.

The files in %localappdata% don't need to be touched at all.

Only thing to move into RAM are DiskCacheArena and some texture packages, since your using junctions, junctions are pointers/references to the files that are copied to RAM.

You don't need to move any folder there, wouldn't make sense to hardlink either.

To keep the settings between boots, you either add a script to task scheduler or group policy (need Pro a minimum for group policy), that copies the files up into RAM at boot, or the imdisk image.

If using an imdisk image: for patching purposes there needs to be a shutdown script as well, so that we get a fresh imdisk image created, else you will have old files upon the next every boot which then will updated every single time.

It's exact the same thing that was done with LOTRO textures btw.

Edited February 15, 2012 by Mineria

Robbipl · February 15, 2012

When I am doing this (typing last line) it says that system can't find this directory.

Ocmer_ · February 15, 2012

That doesn't make any sense.
The files in %localappdata% don't need to be touched at all.
Only thing to move into RAM are DiskCacheArena and some texture packages, since your using junctions, junctions are pointers/references to the files that are copied to RAM.

Well I am only following Lemon_Kings original how-to while I made the batch scripts. A quote from the OP "Right now this focuses on placing DiskCacheArena and 2 buffer files DiskCacheStatic / DiskCacheStream on a RamDrive.".

And guess what, the two buffer files are located in the local SWTOR folder. Think a while back Lemon_King said something having these on ramdisk was the biggest improvement (althou you don't say because most of the time these are 0kB but during loadingscreens these get used). And I also tought that he said by the nature of these files (being deleted/created) he could not link them with a symlink thus he had to junction the while SWTOR folder in local.

Edit;

I just confirmed it aswell, creating a symlink for 'DiskCacheStatic' and 'DiskCacheStream' to the ramdisk had no effect, as the game removes these files (thus the links) at startup and recreates them. (These files are also gone when you quit the game).

Edited February 15, 2012 by Ocmer_

DarkSirius · February 15, 2012

Did you rename SWTOR in Local to SWTOR_Original, after you made a copy of it?
If you didn't your settings for each boot will become temp.

Steps 3 - 5.
3: Scrolling down you should see a folder called SWTOR, open it and Copy the settings folder to <SWTOR Install Location>\Star Wars-The Old Republic\SWTOR\retailclient\
4: Delete DiskCacheArena if it exists in <SWTOR Install Location>\Star Wars - The Old Republic\SWTOR\
5: RENAME the SWTOR folder in Local to SWTOR_Original

Yep, did all of that.

jayromandell · February 16, 2012

I also get the message that it cant find the path or whatever in the last line of the commnad. Here is what I have been using:

mkdir T:\SWTOR\swtor

mklink /J "%userprofile%\AppData\Local\SWTOR" "T:\SWTOR\"

mklink /J "T:\SWTOR\swtor\settings" "C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\SWTOR\retailclient\settings"

mklink "C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\SWTOR\DiskCacheArena" "T:\DiskCacheArena"

All is well except for the last line. What have i done wrong lol.?

What is says is taht the system cannot find the specified path.

Edited February 16, 2012 by jayromandell

Ocmer_ · February 16, 2012

I also get the message that it cant find the path or whatever in the last line of the commnad. Here is what I have been using:

mkdir T:\SWTOR\swtor
mklink /J "%userprofile%\AppData\Local\SWTOR" "T:\SWTOR\"
mklink /J "T:\SWTOR\swtor\settings" "C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\SWTOR\retailclient\settings"
mklink "C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\SWTOR\DiskCacheArena" "T:\DiskCacheArena"

All is well except for the last line. What have i done wrong lol.?

What is says is taht the system cannot find the specified path.

Try;

mklink "C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars - The Old Republic\SWTOR\DiskCacheArena" "T:\DiskCacheArena"

As the installpath for the beta was without spaces around the '-' and a new install now has spaces around it.

Ocmer_ · February 16, 2012

[bATCH SCRIPTS] SWTOR RAMDISK ALL-IN-ONE

This "ALL-IN-ONE SWTOR RAMDISK" batch script can do the following;

Setup your SWTOR to use a ramdisk.
Remove the ramdisk setup.
Mount the ramdrive (separate script available).
Dismount the ramdrive (to free up memory between game sessions).

NEW FEATURE VERSION 4.0.0 AND UP

Add only the asset files to the script you want to use. Due this nature, changing the settings of the script now, you the user have to remove the setup first with the current settings before making any changes and rerunning the setup!

WARNING FOR USE AFTER SETUP PRIOR VERSION 4.0.0

Due to the changes in 4.0.0 and late you have to remove the setup first with the version you used to setup the ramdrive. After that you can safely run the setup with the newer versions, and add dynamically asset files you want to use as they are not pre programmed anymore.

Warning for those who add asset files to the ramdisk:

The client can return an error when it wants to patch, as it cannot patch while there is a assetfile being linked to another location. To be able to patch remove the ramdisk setup first, patch the game, and rerun the ramdisk setup again.

Warning with using the batchscrips:

Always run the batchscrips as administrator, as I cannot guarantee correct exectution without it. To execute as administrator, right-click on the batchscrips (.bat) and select 'Run as administrator'.

INSTRUCTIONS (PLEASE READ)

Creating batchscript

Copy the ALL-IN-ONE batchscript.
Open notepad.
Paste the copied batchscript into notepad.
Change user settings if wanted (see next spoiler in the post).
Save as with the name; anyname.bat (.bat is important!).
Press save.
Batchscript created (check if the icon is not a textfile anymore).
Do the same for the MOUNT batchscrip (if you wish to use it).

Setup SWTOR for ramdisk

Be able to run SWTOR without a ramdisk.
Have Imdisk installed on your machine (can be changed in script now).
Run the created/selected batchscript as administrator.
Once in the menu press 's' on your keyboard to setup.
Once you confirmed the message of a clean setup press 'y' on your keyboard.
Start the game.

What to do on a reboot / dismount

Use the MOUNT batchscript (can be used as computer startup script):
1. Run the MOUNT batchscript as administrator.
2. Start the game
[*]Use the ALL-IN-ONE batchscript (human interaction is needed):
1. Run the ALL-IN-ONE script as administrator.
2. Once in the menu press 'm' on your keyboard to mount the ramdrive.
3. Start the game.

Dismount ramdrive (to free up memory)

Run the ALL-IN-ONE batchscript as administrator.
Once in the menu press 'd' on your keyboard to dismount the ramdrive.

Remove the ramdisk setup

Run the ALL-IN-ONE batchscript as administrator (make sure settings are same when you did the setup).
Once in the menu press 'r' on your keyboard to remove the ramdisk setup.
Uninstall Imdisk if preferred.

SCRIPT SETTINGS (INCLUDING ASSET FILES)

Auto start the launcher after mounting;

Change line [15] 'set AutoLaunch=no' to 'set AutoLaunch=yes'.

Change driveletter of the ramdisk;

Change line [19] 'set RamDrive=T:' to 'set RamDrive=Z:' if you want it as Z:

Change ramdisk volume size;

Change line [26] set RamSize=1500M' to set RamSize=4000M' if you want it as 4GB.
Some recommended sizes;
- Cache files only use '1500M'.
- Cache files + Fx asset file use '1600M'.
- Cache + Fx asset file + Dynamic asset files use '4G'.

Add asset files to the ramdisk setup;

To add asset files to the ramdisk you need to know the filenames of those files you want to add.

Once you know the filenames you add lines the following way;

For asset file 1 add the line 'set AssetFile01=NAME_OF_FILE_1'.
For asset file 2 add the line 'set AssetFile02=NAME_OF_FILE_2'.
For asset file 3 add the line 'set AssetFile03=NAME_OF_FILE_3'.

In the script the fx and dynamic asset files already placed but are commented out with a double colon (:.

To use them, just remove the :: and make sure the number add up, 01->02->03->ect.

Override installationpath, for if the script can't find it;

Rightclick on your SWTOR launcher shortcut, and select properties.
Go to the 'shortcut' tab if it isn't showing automatically.
Copy the link that is given in the 'Start in:' box (without the quotes "..").
Paste the path you copied behind 'InstallPath=' (line 54) without any spaces around the =.
Example: 'set InstallPath=D:\EA\SWTOR'.

Don't use Imdisk with setup/mounting;

Change line [48] 'set UseImdisk=yes' to 'set UseImdisk=no'.
Have another program create the ramdisk before you run the setup/mount.

Please make sure the given RamSize is sufficient enough (minimal or more), because this batchscrip does not check the amount of free space on the created ramdrive!

ALL-IN-ONE v4.0.0

Please read the instructions and changing settings before using.

Always run as administrator, as I cannot guarantee correct exectution without.

:: SCRIPT VERSION 4.0.0 @ 21-03-2012
:: SWTOR FORUM THREAD: http://www.swtor.com/community/showthread.php?t=154568
:: SCRIPT INSTRUCTION: http://www.swtor.com/community/showpost.php?p=2892331
:: Use the thread for questions, feedback or debugging.

@echo off
color f0

:: ==================================================================================
:: USER SETTINGS [ set <varname>=<value>  ; Do not add spaces around the = sign !! ]
:: ==================================================================================

:: Start SWOTR's Launcher after mounting the ramdrive
:: use 'set AutoLaunch=yes' or 'set AutoLaunch=no'
set AutoLaunch=no

:: Give the diskletter you want to use as ramdisk
:: Give a letter followed by a colon (default is T:)
set RamDrive=T:

:: Give the ramdisk size, [interger+suffix] M for MegaByte or G for GigaByte
:: - only adding cache (default):   1500M
:: - Cache + Fx asset:              1600M
:: - Cache + Fx + Dynamic:          4G
:: - Cache + Dynamic:               4G
set RamSize=1500M

:: Add asset files, make sure RamSize if of sufficient size!
:: To include asset files use 'set AssetFileXX=name_of_asset' where XX represents
:: the number of asset file that has to be included starting with '01'. (leave out .tor)
:: Example; set AssetFile01=swtor_main_art_fx_1 to include fx asset file to the ramdisk.
:: predefined asset files remove the double colon (: to uncomment it and add it


::set AssetFile01=swtor_main_art_fx_1
::set AssetFile02=swtor_main_art_dynamic_cape_1
::set AssetFile03=swtor_main_art_dynamic_chest_1
::set AssetFile04=swtor_main_art_dynamic_chest_tight_1
::set AssetFile05=swtor_main_art_dynamic_hand_1
::set AssetFile06=swtor_main_art_dynamic_head_1
::set AssetFile07=swtor_main_art_dynamic_lower_1
::set AssetFile08=swtor_main_art_dynamic_mags_1


:: Use Imdisk, if set to 'no' it will skip the creation of a ramdisk by using Imdisk.
:: So an user has to create a ramdisk before hand with the right amount of size
:: and press y during confirmation while executing this script.
set UseImdisk=yes

:: Override Installpath for use when this script cannot read the path from registery.
:: This can happen because a reinstall of Windows while SWTOR was on another disk.
:: To use, add the complete path (no quotes) behind 'set InstallPath=' for example:
:: set InstallPath=C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars - The Old Republic
set InstallPath=

:: ==================================================================================
:: GET INSTALLPATH AND LOCALPATH FROM REGISTERY
:: ==================================================================================
:: Get SWTOR installation path, if manually given skip this
if defined InstallPath goto OverrideInstallPath
for /F "skip=2 tokens=3,*" %%i in ('reg query "HKEY_LOCAL_MACHINE\software\wow6432node\bioware\star wars-the old republic" /v "Install Dir" 2^>nul') do set InstallPath=%%j
if not defined InstallPath goto ErrorInstallPath

:OverrideInstallPath
:: Get local appdata path
for /F "skip=2 tokens=3,*" %%i in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Local AppData" 2^>nul') do set AppLocal=%%j
if not defined AppLocal goto ErrorAppLocalPath

:: Validate found/given installation path
if not exist "%InstallPath%\launcher.exe" goto ErrorWrongInstallPath

:: ==================================================================================
:: BASIC SYSTEM VALIDATIONS (64bit test, ntfs test, imdisk test)
:: ==================================================================================
:: Check if the used system is 64bit
if not %PROCESSOR_ARCHITECTURE% == AMD64 goto ErrorNo64Bit

:: NTFS check for both local drive and SWTOR drive
if exist %AppLocal:~0,2%\swtorramdiskntfstest.temp del %AppLocal:~0,2%\swtorramdiskntfstest.temp
@echo 1 > %AppLocal:~0,2%\swtorramdiskntfstest.temp:stream
if not exist %AppLocal:~0,2%\swtorramdiskntfstest.temp goto ErrorNTFS
del %AppLocal:~0,2%\swtorramdiskntfstest.temp

if exist %InstallPath:~0,2%\swtorramdiskntfstest.temp del %InstallPath:~0,2%\temp.temp
@echo 1 > %InstallPath:~0,2%\swtorramdiskntfstest.temp:stream
if not exist %InstallPath:~0,2%\swtorramdiskntfstest.temp goto ErrorNTFS
del %InstallPath:~0,2%\swtorramdiskntfstest.temp

:: Check if Imdisk is installed (imdisk.exe in system32)
if %UseImdisk% == no goto SkipImdiskCheck
if not exist "%SYSTEMROOT%\system32\imdisk.exe" goto ErrorNoImdisk
:SkipImdiskCheck

:: ==================================================================================
:: VARIABLE
:: ==================================================================================
:: Create variable for assetfile errors
set "AssetError="

:: ==================================================================================
:: USER MENU
:: ==================================================================================
:MENU
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º          RAMDISK SETUP OR REMOVAL FOR STAR WARS THE OLD REPUBLIC           º
echo  º                               VERSION: 4.0.0                               º
echo  º                                                                            º
echo  º                Created by: Ocmer_   Forumthread: Lemon_King                º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo Script Settings:
echo     - Ramdisk driveletter:    %RamDrive%
echo     - Ramdisk size:           %RamSize%
echo     - Auto start Launcher:    %AutoLaunch%
echo.
echo Menu:
echo     [s] Setup and prepare SWTOR for a ramdisk.
echo     [R] Remove the ramdisk setup for SWTOR.
echo     [M] Mount a ramdrive for SWTOR (separate smaller script available!)
echo     [D] Dismount the ramdrive to free memory (Mount again if you want to play)
echo     [Q] Quit this script.
echo.
echo If everything is executed correctly without any errors, this script will close.
echo This script only notifies the user when an error occurred.
echo.
choice /c:srmdq /n /m "Press one of the menu items:"
if errorlevel 5 goto EOS
if errorlevel 4 goto DISMOUNT
if errorlevel 3 goto MOUNT
if errorlevel 2 goto REMOVE
if errorlevel 1 goto SETUP

:: ==================================================================================
:: SETUP RAMDISK
:: ==================================================================================
:SETUP
cls

:: Pre warning for use with ALL-IN-ONE version 4.0.0 and up
:: As asset files are not fixed anymore, extra caution has to be taken
echo Running the setup with this ALL-IN-ONE batchscript version 4.0.0 and up extra
echo caution has to be taken into account. Therefor the following question:
echo.
echo Do you run this setup without running SWTOR with a ramdisk setup?
echo.
echo If you do press y to continue the setup.
echo.
echo If you don't, please remove the setup first before making any changes to this
echo batchscript or useing the setup again. If you did make changes please put the
echo settings back how they were when you ran the setup.
echo.
choice /c:yn /m "Do you run a SWTOR without a ramdisk or you removed it first"
if errorlevel 2 goto MENU
if errorlevel 1 goto ContinueSetup1

:ContinueSetup1

:: Check if the user uses another ramdisk program
:: If not start with dismounting a current ramdrive to start fresh, then create
if %UseImdisk% == yes (
 if exist %RamDrive% imdisk -D -m %RamDrive%
 imdisk -a -s %RamSize% -m %RamDrive% -p "/v:SWTOR_RAM /fs:ntfs /q /y"
) else (
 choice /c:yn /m "Did you mount a ramdrive with sufficient size already"
 if errorlevel 2 goto MENU
 if errorlevel 1 goto ContinueSetup2
)

:ContinueSetup2

:: Create ramdisk folders, needed to link local to ramdisk
mkdir "%RamDrive%\SWTOR\swtor"

:: Check if local SWTOR is a junction already, if not create a fresh copy of it
for %%F in ("%AppLocal%\SWTOR") do set ATTRIBS=%%~aF
if %ATTRIBS:~8,1% == - (
 if exist "%AppLocal%\SWTOR_Original" rmdir "%AppLocal%\SWTOR_Original" /S /Q
 ren "%AppLocal%\SWTOR" SWTOR_Original
)

:: If for some reason SWTOR_Original does not exist on this point, recreate it
:: Tho settings will be lost now if this line has to be executed!
if not exist "%AppLocal%\SWTOR_Original" mkdir "%AppLocal%\SWTOR_Original\swtor\settings"

:: If an older junction exist of local SWTOR delete it and recreate it to ramdisk
if exist "%AppLocal%\SWTOR" rmdir "%AppLocal%\SWTOR" /S /Q
mklink /J "%AppLocal%\SWTOR" "%RamDrive%\SWTOR"

:: Create settings (from ramdisk) junction to SWTOR_Original in local
mklink /J "%RamDrive%\SWTOR\swtor\settings" "%AppLocal%\SWTOR_Original\swtor\settings"

:: Delete DiskCacheArena (regardless if original or symlink) and create a symlink to ramdrive
if exist "%InstallPath%\swtor\DiskCacheArena" del "%InstallPath%\swtor\DiskCacheArena"
mklink "%InstallPath%\swtor\DiskCacheArena" "%ramdrive%\DiskCacheArena"

:: Add asset files if user has set the vars
for /F "usebackq tokens=1* delims==" %%i in (`set AssetFile`) do (
call :CreateLink %%j
)

:: Copy asset files to the ramdisk if user has set the vars
for /F "usebackq tokens=1* delims==" %%i in (`set AssetFile`) do (
call :CopyAsset %%j
)

:: Check if there were any asset file errors during copying
if defined AssetError goto ErrorAssetMsgCopy

:: Check if the user wants to start the launcher after mounting
if %AutoLaunch% == yes goto LAUNCH

:: End Of Script
goto EOS

:: ==================================================================================
:: REMOVE RAMDISK
:: ==================================================================================
:REMOVE
cls

:: Dismount the ramdrive if the drive exists and the user is using Imdisk
if %UseImdisk% == yes (
 if exist %RamDrive% imdisk -D -m %RamDrive%
)

:: Delete DiskArenaCache, regardless if original or symlink
if exist "%InstallPath%\swtor\DiskCacheArena" del "%InstallPath%\swtor\DiskCacheArena"

:: Delete local SWTOR link
for %%F in ("%AppLocal%\SWTOR") do set ATTRIBS=%%~aF
if %ATTRIBS:~8,1% == l (
 rmdir "%AppLocal%\SWTOR" /S /Q
 if not exist "%AppLocal%\SWTOR_Original" mkdir "%AppLocal%\SWTOR\swtor\settings"
 if exist "%AppLocal%\SWTOR_Original" ren "%AppLocal%\SWTOR_Original" SWTOR
) else (
 if exist "%AppLocal%\SWTOR_Original" rmdir "%AppLocal%\SWTOR_Original" /S /Q
)

:: Restore Asset files 
for /F "usebackq tokens=1* delims==" %%i in (`set AssetFile`) do (
call :RemoveLink %%j
)

:: Check if there were any asset file errors during removing
if defined AssetError goto ErrorAssetMsgRemove

:: End Of Script
goto EOS

:: ==================================================================================
:: MOUNT RAMDISK FOR SWTOR
:: ==================================================================================
:MOUNT
cls

:: Check if the user uses another ramdisk program
:: If not start with dismounting a current ramdrive to start fresh, then create
if %UseImdisk% == yes (
 if exist %RamDrive% imdisk -D -m %RamDrive%
 imdisk -a -s %RamSize% -m %RamDrive% -p "/v:SWTOR_RAM /fs:ntfs /q /y"
)

:: Create ramdisk folders
mkdir "%RamDrive%\SWTOR\swtor"

:: Create settings junction to SWTOR_Original in local
mklink /J "%RamDrive%\SWTOR\swtor\settings" "%AppLocal%\SWTOR_Original\swtor\settings"

:: Copy asset files to the ramdisk if user has set the vars
for /F "usebackq tokens=1* delims==" %%i in (`set AssetFile`) do (
call :CopyAsset %%j
)

:: Check if there were any asset file errors during copying
if defined AssetError goto ErrorAssetMsgCopy

:: Check if the user wants to start the launcher after mounting
if %AutoLaunch% == yes goto LAUNCH

:: End Of Script
goto EOS

:: ==================================================================================
:: DISMOUNT THE RAMDRIVE TO FREE MEMORY BETWEEN GAME SESSIONS
:: ==================================================================================
:DISMOUNT
cls

imdisk -D -m %RamDrive%
goto EOS

:: ==================================================================================
:: MESSAGES
:: ==================================================================================
:ErrorNo64Bit
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo This script is currently written only for 64bit users of Windows, and having
echo more than 6GB of internal RAM available. Reason is because the creating a
echo ramdisk in this current state does not use 'hidden memory' on 32bit systems.
echo.
echo If this error not correct, please post this error in the ramdisk thread created
echo by Lemon_King. You can find the link on the first line of this script.
pause
goto EOS

:ErrorNTFS
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo This script has determinate that either the disk where your local appdata or
echo the disk where you installed SWTOR does not have NTFS as filesystem. Creating
echo links can only be done with a NTFS filesystem, hence the check.
echo.
echo If this error not correct, please post this error in the ramdisk thread created
echo by Lemon_King. You can find the link on the first line of this script.
echo.
pause
goto EOS

:ErrorNoImdisk
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo Please install Imdisk prior to executing this script, as it uses Imdisk.
echo.
echo This script could not find imdisk.exe in system32 thus thinking Imdisk is not
echo yet installed on this machine, and stopped the script.
echo.
echo If this error not correct, please post this error in the ramdisk thread created
echo by Lemon_King. You can find the link on the first line of this script.
pause
goto EOS

:ErrorInstallPath
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo Could not find the installation path of SWTOR, by reading the registery.
echo.
echo This can come if you installed SWTOR on a different disk than the OS, and by
echo reinstalling Windows afterwards, the registery entry is not made.
echo.
echo To manually add the installation path to this scrip look at the usersettings,
echo of this batchscript, how to add manually an installation path.
echo.
pause
goto EOS

:ErrorWrongInstallPath
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo The found (by registery) or given (manual added at settings) installationpath
echo could not find launcher.exe thus the found/given installationpath is wrong.
echo.
echo If you did not add manually an installationpath in the scrip settings, please
echo add it now, as the one in the registery is wrong.
echo.
echo If you did add it manually, please recheck the given installationpath.
echo.
pause
goto EOS

:ErrorAppLocalPath
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo Could not find the path to local application data, by reading the registery.
echo.
echo Please follow the manual steps written out by Lemon_King on the SWTOR forums,
echo you can find the link on the first line of this script.
echo.
pause
goto EOS

:ErrorAssetMsgCopy
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo This script could not find an original renamed asset file on your computer.
echo This is needed to copy them to the ramdisk as the game will look there now.
echo.
echo Please add the missing asset files listed below with the suffix _ORIG.tor to
echo the Asset folder that can be found at the root folder of the game.
echo.
echo The missing asset file(s) are:
echo %AssetError%
echo.
pause
goto EOS

:ErrorAssetMsgRemove
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo This script could not find an original renamed asset file on your computer.
echo This is needed to rename it back as the link is removed already.
echo.
echo Please add the missing asset files listed below with the without the suffix
echo _ORIG.tor to the Asset folder that can be found at the root folder of the game.
echo.
echo The missing asset file(s) are:
echo %AssetError%
echo.
pause
goto EOS

:: ==================================================================================
:: LAUNCH THE SWTOR LAUNCHER
:: ==================================================================================
:LAUNCH
set InstallDrive=%InstallPath:~0,2%
%InstallDrive%
cd %InstallPath%
start "" "%InstallPath%\launcher.exe" /MIN
goto EOS

:: ==================================================================================
:: FUNCTIONS TO CALL
:: ==================================================================================
:CreateLink
for %%F in ("%InstallPath%\Assets\%1.tor") do set ATTRIBS=%%~aF
if %ATTRIBS:~8,1% == l (
 del "%InstallPath%\Assets\%1"
 mklink "%InstallPath%\Assets\%1.tor" "%RamDrive%\%1.tor"
) else (
 if exist "%InstallPath%\Assets\%1_ORIG.tor" del "%InstallPath%\Assets\%1_ORIG.tor"
 ren "%InstallPath%\Assets\%1.tor" "%1_ORIG.tor"
 mklink "%InstallPath%\Assets\%1.tor" "%RamDrive%\%1.tor"
)
goto :eof
:: end of function CreateLink

:RemoveLink
for %%F in ("%InstallPath%\Assets\%1.tor") do set ATTRIBS=%%~aF
if %ATTRIBS:~8,1% == l (
 del "%InstallPath%\Assets\%1.tor"
 if not exist "%InstallPath%\Assets\%1_ORIG.tor" set "AssetError=%AssetError% %1.tor"
 ren "%InstallPath%\Assets\%1_ORIG.tor" "%1.tor"
) else (
 if exist "%InstallPath%\Assets\%1_ORIG.tor" del "%InstallPath%\Assets\%1_ORIG.tor"
)
goto :eof
:: end of function RemoveLink

:CopyAsset
if not exist "%InstallPath%\Assets\%1_ORIG.tor" set "AssetError=%AssetError% %1_ORIG.tor"
copy "%InstallPath%\Assets\%1_ORIG.tor" "%RamDrive%"
ren "%RamDrive%\%1_ORIG.tor" "%1.tor"
goto :eof
:: end of function CopyAsset

:: ==================================================================================
:: END OF SCRIPT
:: ==================================================================================
:EOS
exit

MOUNTSCRIPT v4.0.0

To be used for the creating the ramdrive with asset files if needed (no interaction needed).

This can also be used as startup script for Windows if preferred.

:: SCRIPT VERSION 4.0.0 @ 21-03-2012
:: SWTOR FORUM THREAD: http://www.swtor.com/community/showthread.php?t=154568
:: SCRIPT INSTRUCTION: http://www.swtor.com/community/showpost.php?p=2892331
:: Use the thread for questions, feedback or debugging.

@echo off
color f0

:: ==================================================================================
:: USER SETTINGS [ set <varname>=<value>  ; Do not add spaces around the = sign !! ]
:: ==================================================================================

:: Start SWOTR's Launcher after mounting the ramdrive
:: use 'set AutoLaunch=yes' or 'set AutoLaunch=no'
set AutoLaunch=no

:: Give the diskletter you want to use as ramdisk
:: Give a letter followed by a colon (default is T:)
set RamDrive=T:

:: Give the ramdisk size, [interger+suffix] M for MegaByte or G for GigaByte
:: - only adding cache (default):   1500M
:: - Cache + Fx asset:              1600M
:: - Cache + Fx + Dynamic:          4G
:: - Cache + Dynamic:               4G
set RamSize=1500M

:: Add asset files, make sure RamSize if of sufficient size!
:: To include asset files use 'set AssetFileXX=name_of_asset' where XX represents
:: the number of asset file that has to be included starting with '01'. (leave out .tor)
:: Example; set AssetFile01=swtor_main_art_fx_1 to include fx asset file to the ramdisk.
:: predefined asset files remove the double colon (: to uncomment it and add it


::set AssetFile01=swtor_main_art_fx_1
::set AssetFile02=swtor_main_art_dynamic_cape_1
::set AssetFile03=swtor_main_art_dynamic_chest_1
::set AssetFile04=swtor_main_art_dynamic_chest_tight_1
::set AssetFile05=swtor_main_art_dynamic_hand_1
::set AssetFile06=swtor_main_art_dynamic_head_1
::set AssetFile07=swtor_main_art_dynamic_lower_1
::set AssetFile08=swtor_main_art_dynamic_mags_1


:: Use Imdisk, if set to 'no' it will skip the creation of a ramdisk by using Imdisk.
:: So an user has to create a ramdisk before hand with the right amount of size
:: and press y during confirmation while executing this script.
set UseImdisk=yes

:: Override Installpath for use when this script cannot read the path from registery.
:: This can happen because a reinstall of Windows while SWTOR was on another disk.
:: To use, add the complete path (no quotes) behind 'set InstallPath=' for example:
:: set InstallPath=C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars - The Old Republic
set InstallPath=

:: ==================================================================================
:: GET INSTALLPATH AND LOCALPATH FROM REGISTERY
:: ==================================================================================
:: Get SWTOR installation path, if manually given skip this
if defined InstallPath goto OverrideInstallPath
for /F "skip=2 tokens=3,*" %%i in ('reg query "HKEY_LOCAL_MACHINE\software\wow6432node\bioware\star wars-the old republic" /v "Install Dir" 2^>nul') do set InstallPath=%%j
if not defined InstallPath goto ErrorInstallPath

:OverrideInstallPath
:: Get local appdata path
for /F "skip=2 tokens=3,*" %%i in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Local AppData" 2^>nul') do set AppLocal=%%j
if not defined AppLocal goto ErrorAppLocalPath

:: Validate found/given installation path
if not exist "%InstallPath%\launcher.exe" goto ErrorWrongInstallPath

:: ==================================================================================
:: MOUNT RAMDISK FOR SWTOR
:: ==================================================================================
:MOUNT
cls

:: Check if the user uses another ramdisk program
:: If not start with dismounting a current ramdrive to start fresh, then create
if %UseImdisk% == yes (
 if exist %RamDrive% imdisk -D -m %RamDrive%
 imdisk -a -s %RamSize% -m %RamDrive% -p "/v:SWTOR_RAM /fs:ntfs /q /y"
)

:: Create ramdisk folders
mkdir "%RamDrive%\SWTOR\swtor"

:: Create settings junction to SWTOR_Original in local
mklink /J "%RamDrive%\SWTOR\swtor\settings" "%AppLocal%\SWTOR_Original\swtor\settings"

:: Copy asset files to the ramdisk if user has set the vars
for /F "usebackq tokens=1* delims==" %%i in (`set AssetFile`) do (
call :CopyAsset %%j
)

:: Check if there were any asset file errors during copying
if defined AssetError goto ErrorAssetMsgCopy

:: Check if the user wants to start the launcher after mounting
if %AutoLaunch% == yes goto LAUNCH

:: End Of Script
goto EOS

:: ==================================================================================
:: MESSAGES
:: ==================================================================================
:ErrorInstallPath
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo Could not find the installation path of SWTOR, by reading the registery.
echo.
echo This can come if you installed SWTOR on a different disk than the OS, and by
echo reinstalling Windows afterwards, the registery entry is not made.
echo.
echo To manually add the installation path to this scrip look at the usersettings,
echo of this batchscript, how to add manually an installation path.
echo.
pause
goto EOS

:ErrorWrongInstallPath
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo The found (by registery) or given (manual added at settings) installationpath
echo could not find launcher.exe thus the found/given installationpath is wrong.
echo.
echo If you did not add manually an installationpath in the scrip settings, please
echo add it now, as the one in the registery is wrong.
echo.
echo If you did add it manually, please recheck the given installationpath.
echo.
pause
goto EOS

:ErrorAppLocalPath
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo Could not find the path to local application data, by reading the registery.
echo.
echo Please follow the manual steps by Lemon_King on the SWTOR forums,
echo search for ramdisk, select the how-to thread.
echo.
pause
goto EOS

:ErrorAssetMsgCopy
cls
echo  ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo  º                                                                            º
echo  º                                   ERROR                                    º
echo  º                                                                            º
echo  ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
echo.
echo This script could not find an original renamed asset file on your computer.
echo This is needed to copy them to the ramdisk as the game will look there now.
echo.
echo Please add the missing asset files listed below with the suffix _ORIG.tor to
echo the Asset folder that can be found at the root folder of the game.
echo.
echo The missing asset file(s) are:
echo %AssetError%
echo.
pause
goto EOS

:: ==================================================================================
:: LAUNCH THE SWTOR LAUNCHER
:: ==================================================================================
:LAUNCH
set InstallDrive=%InstallPath:~0,2%
%InstallDrive%
cd %InstallPath%
start "" "%InstallPath%\launcher.exe" /MIN
goto EOS

:: ==================================================================================
:: FUNCTIONS TO CALL
:: ==================================================================================
:CopyAsset
if not exist "%InstallPath%\Assets\%1_ORIG.tor" set "AssetError=%AssetError% %1_ORIG.tor"
copy "%InstallPath%\Assets\%1_ORIG.tor" "%RamDrive%"
ren "%RamDrive%\%1_ORIG.tor" "%1.tor"
goto :eof
:: end of function CopyAsset

:: ==================================================================================
:: END OF SCRIPT
:: ==================================================================================
:EOS
exit

CHANGELOG

v4.0.0 // 2012-03-21;
- Reduced code quite a bit by use of call functions (thnx 'Morsk').
- Ability to add only the asset files you want, not fixed in code anymore (thnx 'exca').
- Ability to autostart the launcher after mounting.
- Ability to skip the Imdisk parts, for use with another program (thnx 'Black-Mage').
[*]v3.1.3 // 2012-03-06;
- Added forum and post link on top of the script.
- Commented in some errors that these links are available.
- Changed background- and forground-color to white/black instead of black/white.
[*]v3.1.2 // 2012-02-29;
- Changed tempfile name (at ntfs test) to 'swtorramdiskntfstest.temp'. (cosmetic)
- Combined lines at nfts test. (cosmetic)
[*]v3.1.1 // 2012-02-28;
- Changed minimum size cache+fx to 1600M.
[*]v3.1.0 // 2012-02-28;
- Added check if Imdisk is installed.
[*]v3.0.1 // 2012-02-27;
- Fixed a little error at NTFS check
[*]v3.0.0 // 2012-02-27;
- Added option for dynamic asset files.
- Added option to override installpath of SWTOR.
- Added check for correct found/given installpath of SWTOR.
- Added check for Windows 64-bit.
- Added check for NTFS filesystem.
- Added a single errormessage for missing asset files.
- Allot of comments ( :: text ).
[*]v2.x.x // 2012-02-xx;
- Cache+fx all-in-one version.
[*]v1.x.x // 2012-01-xx;
- First all-in-one batchscript, cache only.

Edited March 22, 2012 by Ocmer_

jayromandell · February 16, 2012

So I am getting a syntax error now. Big Ups on the help, and a huge thank you.

Hallel · February 16, 2012

After I run the batch file it asks me to format the new partition. Is this normal?

Ocmer_ · February 16, 2012

After I run the batch file it asks me to format the new partition. Is this normal?

Yes, as Imdisk only reserves a piece of your memory and Windows does not really know what it is until you say it has to be formatted with a filesystem (ntfs in this case).

I am curious tho, does it ask for a confirmation from your side to format the partition? So far as I know the formatting should go automatically by running the Imdisk format switch.

Did you run the script as admin or is your account admin? If not try to run it as administrator. Rightclick on the script, select Run as administrator.

Edited February 16, 2012 by Ocmer_

Ocmer_ · February 16, 2012

So I am getting a syntax error now. Big Ups on the help, and a huge thank you.

At what commandline (or step) are you getting the syntax error?

Edited February 18, 2012 by Ocmer_

Lemon_King · February 16, 2012

[bATCH SCRIPTS] SWTOR RAMDISK ALL-IN-ONE

Added it to the OP, nice job.

jayromandell · February 16, 2012

the last one...bah I have a screenshot but cant figure out how to insert it. Edited February 16, 2012 by jayromandell

Ocmer_ · February 16, 2012

the last one...bah I have a screenshot but cant figure out how to insert it.

Use imagehack for example to upload the picture and post the link on the forum.

Tho running the code:

mklink "C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars - The Old Republic\swtor\DiskCacheArena" "T:\DiskCacheArena"

Should be correct, be sure your total pathname is given to the DiskCacheArena and that both of the pathnames are quoted with " .

Edited February 18, 2012 by Ocmer_

Ocmer_ · February 16, 2012

Added it to the OP, nice job.

Thnx, was just playing a bit now in batch (been a while ;p) so I ended up with having a menu.

Added some extra checks and handling so files won't get lost by different user input.

Might aswell remove the 2 other links from the OP as those are obsolete now. Maybe also mention in the line that it can remove the setup aswell for those interested.

Cheers.

Edited February 18, 2012 by Ocmer_

Hallel · February 16, 2012

Yes, as Imdisk only reserves a piece of your memory and Windows does not really know what it is until you say it has to be formatted with a filesystem (ntfs in this case).

I am curious tho, does it ask for a confirmation from your side to format the partition? So far as I know the formatting should go automatically by running the Imdisk format switch.

Did you run the script as admin or is your account admin? If not try to run it as administrator. Rightclick on the script, select Run as administrator.

Everything worked correctly after running it in Administrator. Thanks.

Lemon_King · February 16, 2012

Thnx, was just playing a bit now in batch (been a while ;p) so I ended up with having a menu.
Added some extra checks and handling so files won't get lost by different user input.

Might aswell remove the 2 other links from the OP as those are obsolete now. Maybe also mention in the line that it can remove the setup aswell for those interested.

Cheers.

Done, removed the 3rd once as it was no longer updated and was a bit redundant due to your new one.

xmayhem · February 17, 2012

I am having significant framerate drops in PvP zones only it seems and in city like hubs.

I read this guide and it is all very confusing to me lol.

Is it too much to ask that the developers just make the client run like it should on PCs that are supposed to be able to handle their game?

sbjessen · February 17, 2012

I am having significant framerate drops in PvP zones only it seems and in city like hubs.

I read this guide and it is all very confusing to me lol.

Is it too much to ask that the developers just make the client run like it should on PCs that are supposed to be able to handle their game?

Exactly my thought..

Ocmer_ · February 17, 2012

@sbjessen

@xmayhem

Well it might sound technical but all we do is placing some cachefiles on the ram. The system is faster with writing/reading files on ram than a HDD/SDD.

If you want to try it out and are not technical i've made a batchscript that does all the commands Lemon_Kings describes automatically. Read up on how to use the script though.

http://www.swtor.com/community/showpost.php?p=2892331

Make sure you have 6GB+ of ram and are running Windows Vista/7 64-bit version. The script should work out of the box (at least i've tried my best to be it like that). Oh and have Imdisk installed already, find the link in the OP.

Edited February 18, 2012 by Ocmer_

Marctraider · February 17, 2012

Anyone tried linking stuff from a reasonably fast USB stick or something similar?

I'm attempting to put the most important files on my iPod (the sustained read isnt that bad) since it contains 8GB of flash the access time should be improved alot.

Practically when you are playing the game and moving around the world the game never reaches high sustained disk reads but rather small reads so I think this will have a positive effect on performance when it reads from flash. (And thats where we want the game to run smooth, no?)

Perhaps the loadscreens are slightly slower but I'm not yet sure about that. Gonna try it now.

DrillThrall · February 17, 2012

If you do that, I'd recommend that the flash media be at least as fast as ReadyBoost specification requirements (which you can test with the Windows System Assessment Tool).

cipher_nemo · February 17, 2012

Anyone tried linking stuff from a reasonably fast USB stick or something similar?

USB flash drives can vary from super cheap, slow pieces of crap to sort of quick, reliable devices. But the biggest problem is that most of them (10:1 ratio) are USB 2.0, which is painfully slow. If you can get a good quality, fast, reliable USB 3.0 thumbdrive it should be fine.

But still you're talking 100-200MB/s transfer speed. A third gen $100 SSD can read at 500-550MB/s. Second gen SSDs around 200-250.

$110 for 520MB/s: http://www.newegg.com/Product/Product.aspx?Item=N82E16820147133

$75 for 525MB/s (after MIR, $90 before): http://www.newegg.com/Product/Product.aspx?Item=N82E16820227725

$65 for 210MB/s: http://www.newegg.com/Product/Product.aspx?Item=N82E16820227393

Edited February 17, 2012 by cipher_nemo

xxbakerboyxx · February 18, 2012

Random thought...

What other "Main Asset" files can I add to the RamDrive to make the game even smoother?

I have 12 GB of RAM so I would like to utilize all of it =) thank you!

Ocmer_ · February 18, 2012

Random thought...

What other "Main Asset" files can I add to the RamDrive to make the game even smoother?

I have 12 GB of RAM so I would like to utilize all of it =) thank you!

I don't know if you read the OP's "experimental stuff" but you might add the dynamic character look into the ram aswell. Experimental suff from Lemon_King.

[HOWTO - RAMDRIVE] Increasing SWTOR System Performance

Recommended Posts

Link to comment

Share on other sites

Top Posters In This Topic

Popular Days

Top Posters In This Topic

Popular Days

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Announcements